Desafio 01 "Triangulo de Pascal"

[JoRgE-1987]

Desarrollar un programa en pascal, que genere automaticamente el triangulo de pascal, donde los lados del triangulo son unos, y las lines son la suma de sus dos superiores: ejemplo:

 ______1______
 _____1_1_____
 ____1_2_1____
 ___1_3_3_1___
 __1_4_6_4_1__
_1_5_10_10_5_1_
1_6_15_20_15_6_1


Cualquier duda Consulten.

Saludos :D

[exe]

Lindo problema. Está bueno verle la interpretación mediante números combinatorios (no sé si alguien le gusta la matemática), puede llegar a salir más simple, cada uno de esos números son números combinatorios. Pueden darse una vuelta por Wikipedia, ahí explica un poco esto.
Ha det bra,
exe

[CID]

Primero creo el array asignandole éstos valores.

1  0  0  0  0  0  0
1  1  0  0  0  0  0
1  2  1  0  0  0  0
1  3  3  1  0  0  0
1  4  6  4  1  0  0
1  5  10 10 5  1  0
1  6  15 20 15 6  1

Y despues creo un string con un formato para mostrarlo en pantalla y quede como el triangulo que propusiste.

Codigo en Delphi.

Código

procedure TForm1.Button1Click(Sender: TObject);
var
  A : array [1..7, 1..7] of integer;
  i, j, z : integer;
  s : string;
begin
  //llenamos el array con los valores necesarios
  for i := 1 to 7 do
    for j := 1 to 7 do
    begin
      if j > i then
        a[i,j] := 0
      else
        if(i > 1) or (j > 1) then
          a[i,j] := a[i-1,j-1] + a[i-1,j]
        else
          a[i,j] := 1;
    end;
 
  //Lo mostramos formateado
  for i := 1 to 7 do
  begin
    if 7 - i >= 1 then
      for z := 1 to 7 - i do
        s := s + '__ | ';
    for j := 1 to i do
    begin
      s := s + FormatFloat('00',A[i,j]) + ' | __ | ';
    end;
    if 7 - i >= 1 then
      for z := 1 to 7 - i do
        s := s + '__ | ';
    s := s + chr(13);
  end;
  Memo1.Lines.SetText(PAnsiChar(s));
end;
 

Finalmente, la salida es ésta:

__ | __ | __ | __ | __ | __ | 01 | __ | __ | __ | __ | __ | __ | __ |
__ | __ | __ | __ | __ | 01 | __ | 01 | __ | __ | __ | __ | __ | __ |
__ | __ | __ | __ | 01 | __ | 02 | __ | 01 | __ | __ | __ | __ | __ |
__ | __ | __ | 01 | __ | 03 | __ | 03 | __ | 01 | __ | __ | __ | __ |
__ | __ | 01 | __ | 04 | __ | 06 | __ | 04 | __ | 01 | __ | __ | __ |
__ | 01 | __ | 05 | __ | 10 | __ | 10 | __ | 05 | __ | 01 | __ | __ |
01 | __ | 06 | __ | 15 | __ | 20 | __ | 15 | __ | 06 | __ | 01 | __ |


A ver si alguno logra realizar los dos pasos simultaneamente.
Saludos!

[JoRgE-1987]

Muy bien, lo resolviste bastante rapido, yo tarde por lo menos un dia entero.

Saludos :D

PD. No se lee bien el codigo que pusiste, aparece cortado.

//Lo mostramos formateado

  for i := 1 to 7 do

  begin

Hasta aca, nada mas se ve.

[CID]

Yo lo veo bien, tratá cambiando el tema que usas en el foro:
En Perfil, luego Configuración de Apariencia y Diseño y por último Tema actual: algo (cambiar) <----- click
Yo uso xtSMF Theme! con Firefox y se ve muy lindo.

Saludos!

[JoRgE-1987]

Si, ya se como se cambia un tema.
De todas maneras, no lo voy a cambiar, porque me gusta el tema que uso.

Saludos :D

PD: No podes usar Firefox, es malisimo.

PD: Al final me convenciste, ya que este tema, tambien esta lindo, no puedo creer, que hice algo que no queria.
Ta bueno este tema ehh.

[exe]

Acá hice algo usando combinatoria, y para imprimir el cuadro basandome en la rutina de CID.
No sé Pascal, asi que probablemente haya mejores maneras de hacer lo que hice, críticas constructivas y destructivas serán bienvenidas y aceptadas.

Código:

program PascalTriangle;
// Para usar Format()
uses sysutils;

// Función recursiva para calcular el factorial.
FUNCTION Fact ( i : INTEGER ) : INTEGER;
BEGIN
    IF (i = 1) OR (i = 0) THEN
        Fact := 1
    ELSE
        Fact := i * Fact (i-1);
END;

// Función para calcular un número combinatorio.
FUNCTION Comb ( i,j : INTEGER ) : INTEGER;
BEGIN
    Comb := Fact (i) DIV ( Fact (i-j) * Fact (j) );
END;

// Main()
VAR
    j,h : INTEGER;
    s : STRING;
CONST
    i = 7;
BEGIN
    FOR j := 0 TO i DO
    BEGIN
        s := '';
        IF i - j >= 0 THEN
            FOR h := 0 TO i - j DO
                s := s + '__| ';
        FOR h := 0 TO j DO
            s := s + Format ( '%2d', [Comb ( j, h )]) + '| __| ';
        IF i - j >= 0 THEN
            FOR h := 0 TO i - j DO
                s := s + '__| ';
        WriteLn (s);
    END;
END.

Ha det bra,
exe